ASTRA by Example

IDEA:

Declare an initial goal that is handled by a single rule. The behaviour implemented in this rule is to display the text “Hello World” to the system console.

CODE:

agent Hello {
    module Console C;

    initial !init();

    rule +!init() {
        C.println("Hello World");
    }
}

OUTPUT:

[main]Hello World

IDEA:

A variation on Hello World in which the agent terminates the program after it has printed out “Hello World”.

This is achieved through the use of the exit() action which is part of the astra.lang.System module.

CODE:

agent Hello {
    module Console C;
    module System S;
    initial !init();

    rule +!init() {
        C.println("Hello World");
        S.exit();
    }
}

OUTPUT:

[main]Hello World

NOTE: The program terminates now after the text is output

IDEA:

A variation on Terminal Hello World in which the main goal event is used rather than a custom initial event.

The main goal is declared for the agent that is the starting point of the agent program (this is an instance of the agent class that you execute to start your ASTRA program).

CODE:

agent Hello {
    module Console C;
    module System S;

    rule +!main(list args) {
        C.println("Hello World");
        S.exit();
    }
}

OUTPUT:

[main]Hello World

IDEA:

Simple program to illustrate the use of sub goals to drive agent behaviour.

CODE:

agent Subby {
    module Console C;
    module System S;

    rule +!main(list args) {
        C.println("Before Subgoal");
        !printHello();
        C.println("After Subgoal");
        S.exit();
    }

    rule +!printHello() {
        C.println("Hello World"); 
    }
}

OUTPUT:

[main]Before Subgoal
[main]Hello World
[main]After Subgoal

IDEA:

This program illustrates how the belief query statement works in ASTRA. Specifically, you will see that the plan rule listed below is only partially executed, and in fact fails when trying to perform the second query, which if for a belief that is not true.

CODE:

agent Believer {
    module Console C;
    module System S;
 
    types eg {
        formula is(string, string);
    }
 
    initial !init();
    initial is("rem", "happy");

    rule +!init() {
        C.println("starting");
        query(is("rem", "happy"));
        C.println("first hurdle passed");
        query(is("rem", "sad"));
        C.println("ending");
        S.exit();
    }
}

OUTPUT:

[main]starting
[main]first hurdle passed
Could not resolve query: is("rem","sad")
part1.Believer.query(is("rem","sad")):18
+!init()

Copy and paste to create more